Read a gzip body without length from a socket stream

repository/Zinc-HTTP.package/ZnEntityReader.class/instance/readEntityFromStream.st

@@ -4,7 +4,11 @@ readEntityFromStream
 	chunkedStream := (isChunked := self isChunked) ifTrue: [ stream := ZnChunkedReadStream on: stream ] ifFalse: [ nil ].
 	self isGzipped
 		ifTrue: [
-			self hasContentLength ifTrue: [ stream := ZnLimitedReadStream on: stream limit: self contentLength ].
+			self hasContentLength
+				ifTrue: [ stream := ZnLimitedReadStream on: stream limit: self contentLength ]
+				ifFalse: [
+					"InflateStream asks its source for its position, which a socket stream cannot answer"
+					isChunked ifFalse: [ stream := ZnLimitedReadStream on: stream limit: SmallInteger maxVal ] ].
 			decodedEntityLength := nil.
 			stream := GZipReadStream on: stream ]
 		ifFalse: [ decodedEntityLength := self contentLength ].

repository/Zinc-Tests.package/ZnEntityReaderTest.class/instance/testGzippedUpToEndFromUnpositionableStream.st

@@ -0,0 +1,15 @@
+testing
+testGzippedUpToEndFromUnpositionableStream
+	| text compressed headers reader |
+	text := String streamContents: [ :out |
+		1 to: 50000 do: [ :each | out print: each; space ] ].
+	compressed := ByteArray streamContents: [ :out |
+		(GZipWriteStream on: out) nextPutAll: text asByteArray; close ].
+	(headers := ZnHeaders new)
+		at: 'Content-Type' put: 'text/plain';
+		at: 'Content-Encoding' put: 'gzip'.
+	(reader := ZnEntityReader new)
+		headers: headers;
+		stream: (ZnUnpositionableReadStream on: compressed readStream);
+		allowReadingUpToEnd.
+	self assert: reader readEntity contents equals: text

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/README.md

@@ -0,0 +1,3 @@
+I am ZnUnpositionableReadStream. I wrap a read stream but, like a socket stream, I cannot tell my position.
+
+I am used in tests to make sure readers do not depend on a positionable source.

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/class/on..st

@@ -0,0 +1,5 @@
+instance creation
+on: readStream
+	^ self new
+		setStream: readStream;
+		yourself

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/atEnd.st

@@ -0,0 +1,3 @@
+testing
+atEnd
+	^ stream atEnd

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/isBinary.st

@@ -0,0 +1,3 @@
+testing
+isBinary
+	^ true

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/isStream.st

@@ -0,0 +1,3 @@
+testing
+isStream
+	^ true

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/next..st

@@ -0,0 +1,3 @@
+accessing
+next: count
+	^ stream next: count

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/next.into.startingAt..st

@@ -0,0 +1,3 @@
+accessing
+next: count into: collection startingAt: offset
+	^ stream next: count into: collection startingAt: offset

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/next.st

@@ -0,0 +1,3 @@
+accessing
+next
+	^ stream next

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/readInto.startingAt.count..st

@@ -0,0 +1,3 @@
+accessing
+readInto: collection startingAt: offset count: count
+	^ stream readInto: collection startingAt: offset count: count

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/instance/setStream..st

@@ -0,0 +1,3 @@
+initialization
+setStream: readStream
+	stream := readStream

repository/Zinc-Tests.package/ZnUnpositionableReadStream.class/properties.json

@@ -0,0 +1,13 @@
+{
+	"commentStamp" : "",
+	"super" : "Object",
+	"category" : "Zinc-Tests",
+	"classinstvars" : [ ],
+	"pools" : [ ],
+	"classvars" : [ ],
+	"instvars" : [
+		"stream"
+	],
+	"name" : "ZnUnpositionableReadStream",
+	"type" : "normal"
+}